JAR Signier funktioniert nicht

[dsv fritz]

Hallo zusammen,

ich versuch schon seit einiger Zeit ein Applet zu signieren, aber ich schaffs leider nicht.
Dazu habe ich das Script von L-ectron-X verwendet:

@echo off
rem * SignTool by L-ectron-X ( Byte-Welt Forum - Powered by vBulletin )
rem *
rem * Ablauf beim Signieren
rem *
rem * Erzeugen eines eigenen Schlüssels
rem * Mit KeyTool, einem Werkzeug aus dem SDK, einen neuen Schlüssel erzeugen:
rem * keytool -genkey -alias Signer -dname "cn=Dein Name, c=de"
rem * Gib anschließend Dein Passwort ein.
rem
rem * Erzeugen eines Zertifikats
rem * Mit KeyTool Zertifikat erzeugen:
rem * keytool -selfcert -alias Signer -dname "cn=Dein Name, c=de"
rem * Gib anschließend dein Passwort ein.
rem *
rem * Signieren des Applets
rem * Signieren des Applets mit Hilfe des Tools jarsigner
rem * jarsigner signed.jar Signer
rem * Und noch einmal dein Passwort eingeben.

echo = SignTool =
echo Dieses Tool hilft beim Erzeugen von signierten jar-Dateien
echo.
echo Schritt 1: jar-Dateien erzeugen
echo -------------------------------

rem Pfad zum SDK setzen
rem --> anpassen!
set path=.;C:\Program Files\Java\jdk1.6.0_11\bin

echo Manifestdatei erzeugen...
echo Manifest-Version: 1.0>manifest.mf
echo Created-by: SignTool by L-ectron-X>>manifest.mf
echo.>>manifest.mf

if exist *.jar goto key
echo jar-Datei mit angegebenen Parametern erzeugen...
rem --> anpassen!
rem * In diesem Beispiel werden alle .class-Dateien und die Verzeichnisse bilder und etc
rem * mit ins jar-Archiv gepackt.
jar cfmv FileUploadApp.jar manifest.mf *.class

:key
echo.
echo Schritt 2: Schluessel generieren
echo --------------------------------
rem --> anpassen!
keytool -genkey -alias Signer -dname "cn=dsv fritzr, c=ch"

echo.
echo Schritt 3: Zertifikat erzeugen
echo ------------------------------
rem --> anpassen!
rem -validity 18250 (365 Tage x 50) erzeugt ein 50 Jahre gültiges Zertifikat
keytool -selfcert -validity 3650 -alias Signer -dname "cn=dsv fritz, c=ch"

if not exist *.jar goto error
echo.
echo Schritt 4: jar-Datei signieren
echo ------------------------------
echo jarsigner erwartet hier nochmals dein Passwort.
rem --> anpassen!
jarsigner FileUploadApp.jar Signer

echo.
echo Schritt 5: Zertifikat testen
echo ----------------------------
rem --> anpassen!
jarsigner -verify -verbose -certs FileUploadApp.jar
goto end

:error
echo.
echo Es wurde keine jar-Datei zum Signieren gefunden.
echo Die Erzeugung der jar-Datei ist moeglicherweise fehlgeschlagen.
echo Pruefe deine Eingaben in der Batchdatei!

:end
if not exist manifest.mf goto console
echo.
rem Manifest von Festplatte löschen
del manifest.mf

:console
rem Console für Ausgaben noch geöffnet lassen
echo.
pause

Nach Beendigung des Scripts wurde das JAR erstellt, aber nicht signiert:
jar is unsigned

Ich verwende die JDK 1.6 Update 20.

Habe schon einiges ausprobiert, aber ich komme auf keinen grünen Zweig.

Vielen Dank für eure Hilfe.

 

[gman]

Hi,

also die Zeile 29:

set path=.;C:\Program Files\Java\jdk1.6.0_11\bin

stimmt schon mal nicht mit deiner verwendeten Java-Version überein. Hast du
denn sonst alle Stellen über denen:

rem --> anpassen!

steht angepasst? Ich kenne das Original-Skript nicht.

 

[dsv fritz]

Danke, hat jetzt super geklappt!

Copy-Past fehler... aaaarrrrrrrrrggggggggggg