Zeichen in Strings

[Solor]

Hallo alle zusammen,
Hab da ein kleines Problem. Ich habe ein Programm geschrieben, dass die Nullstellen von Funktionen ausrechnen kann. Nun möchte ich noch eine Eingabemöglichkeit für den User schreiben. Dieser soll zuerst den grad der Funktion angeben und dann die Funktionsgleichung in folgender Form angeben:
"3X^4 + 5X^2 - 3X + 4"
Mein Problem liegt nun darin, alle Koeffizienten und Exponenten zu ermitteln. Gibt es eine Möglichkeit nach allen "X" bzw. "^" zu suchen und zu schauen was davor oder dahinter steht?

Vielen Dank schon mal im Voraus
MFG Solor

 

[nillehammer]

Die diversen indexOf- und substring-Methoden von String sollten Dir da weiterhelfen:

private static final String DACH = "^";
....
String funktionsString = "3X^4 + 5X^2 - 3X + 4";
....
int firstDachIndex = funktionsString.indexOf(DACH);

String ersterTeil = funktionsString.substring(0,firstDachIndex);
...

so ganz grob...

 

[HoaX]

Sowas ist ne schöne kleine Aufgabe um sich in das Schreiben von Kompilern/Parsern einzuarbeiten.

Man nehme z.B. Antlr und füttere es mit

grammar polynom;

poly	:	(p=polypart { System.out.println($p.list); })+
	;
	
polypart returns [java.util.List<Object> list]:	
	s=SIGN m=NUMBER 'X' e=exponent { list = new java.util.ArrayList(); list.add($s.text); list.add($m.text); list.add($e.value); }
	| m=NUMBER 'X' e=exponent { list = new java.util.ArrayList(); list.add("+"); list.add($m.text); list.add($e.value); }
	| s=SIGN 'X' e=exponent { list = new java.util.ArrayList(); list.add($s.text); list.add("1"); list.add($e.value); }
	| 'X' e=exponent { list = new java.util.ArrayList(); list.add("+"); list.add("1"); list.add($e.value); }
	
	| s=SIGN m=NUMBER { list = new java.util.ArrayList(); list.add($s.text); list.add($m.text); list.add("0"); }
	| m=NUMBER { list = new java.util.ArrayList(); list.add("+"); list.add($m.text); list.add("0"); }
	;

exponent returns [int value]: ('^' n=NUMBER)? { $value = 1; if ( $n != null && $n.text.length() > 0) $value = Integer.parseInt($n.text); }
	;
	
NUMBER	: '0'..'9'+
	;

SIGN 	:	('+'|'-')
	;

WS  :   (' '|'\t')+ {skip();} ;

Steckt man dann in den Parser "X + 3X - X ^ 6 + 99" als Eingabe, so erhält man als Ausgabe:
[+, 1, 1]
[+, 3, 1]
[-, 1, 6]
[+, 99, 0]

Das erste ist das Vorzeichen, das zweite der Multiplikator, das dritte der Exponent.

 

[Solor]

Danke für die schnellen antworten, aber deins versteh ich nich so ganz, hoaX, könnte aber an meinen wenigen erfahrungen liegen.
Ansonsten probier ichs jetz so, wie weiter oben beschrieben

 

[AquaBall]

HoaX meint, das das keine triviale Aufgabe ist, wenn sie nicht auf sehr wenig Sonderfälle beschränkt wird.

Solange du einen exakt normierte Schreibweise (n*x^4 n*x^3 n*x^2 ...) hast reicht deine einfache Stringzerlegung.
Aber stell dir nur vor, du willst ein bisschen Flexibilität zulassen, oder gar Klammern, zb.
1X^4+2(X^3 +X^2)+X, dann stehst du blitzschnell vor einem enormen Haufen von Problemen.

Dann greift man besser zu Hilfsprogrammen die dir den Text zerlegen (Parsen) und standardisierte Rechenwege ermöglichen (z.B. polnische Notation). Einer dieser Parser ist "Antlr".

Das ist aber einige Stufen höher.

 

[Skrodde]

Man nehme z.B. Antlr und füttere es mit

grammar polynom;

poly	:	(p=polypart { System.out.println($p.list); })+
	;
	
polypart returns [java.util.List<Object> list]:	
	s=SIGN m=NUMBER 'X' e=exponent { list = new java.util.ArrayList(); list.add($s.text); list.add($m.text); list.add($e.value); }
	| m=NUMBER 'X' e=exponent { list = new java.util.ArrayList(); list.add("+"); list.add($m.text); list.add($e.value); }
	| s=SIGN 'X' e=exponent { list = new java.util.ArrayList(); list.add($s.text); list.add("1"); list.add($e.value); }
	| 'X' e=exponent { list = new java.util.ArrayList(); list.add("+"); list.add("1"); list.add($e.value); }
	
	| s=SIGN m=NUMBER { list = new java.util.ArrayList(); list.add($s.text); list.add($m.text); list.add("0"); }
	| m=NUMBER { list = new java.util.ArrayList(); list.add("+"); list.add($m.text); list.add("0"); }
	;

exponent returns [int value]: ('^' n=NUMBER)? { $value = 1; if ( $n != null && $n.text.length() > 0) $value = Integer.parseInt($n.text); }
	;
	
NUMBER	: '0'..'9'+
	;

SIGN 	:	('+'|'-')
	;

WS  :   (' '|'\t')+ {skip();} ;

Wenn ich diese Grammatik mit Antlr kompilieren will, erhalte ich:

warning(200): polynom.g:6:47:
Decision can match input such as "SIGN NUMBER 'X'" using multiple alternatives: 1,5

As a result, alternative(s) 5 were disbaled for that input
warning(200): polynom.g:6:47:
Decision can match input such as "NUMBER 'X'" using multiple alternatives: 2,6

As a result, alternative(s) 6 were disabled for that input

Was heißt das nun genau?

 

[HoaX]

ich komm grad nicht auf antlr.org ... ich schaus mir später mal an.

 

[HoaX]

So ist's nun richtig:

grammar polynom;

poly	: o=SIGN? p=polypart { $p.list.add(0, $o==null?"+":$o.text); System.out.println($p.list); }
	(o2=SIGN p2=polypart { $p2.list.add(0, $o2.text); System.out.println($p2.list); })*

	;
	
polypart returns [java.util.List<Object> list]:	
	m=NUMBER 'X' e=exponent { list = new java.util.ArrayList(); list.add($m.text); list.add($e.value); }
	| m=NUMBER { list = new java.util.ArrayList(); list.add($m.text); list.add("0"); }
	| 'X' e=exponent { list = new java.util.ArrayList(); list.add("1"); list.add($e.value); }
	;

exponent returns [int value]:
	('^' n=NUMBER)? { $value = 1; if ( $n != null && $n.text.length() > 0) $value = Integer.parseInt($n.text); }
	;
	
NUMBER	: '0'..'9'+
	;

SIGN 	:	('+'|'-')
	;

WS  :   (' '|'\t')+ {skip();} ;

War wirklich noch eine Mehrdeutigkeit enthalten.
Angenommen der Input ist: NUMBER X
Dann wäre es nicht klar ob so aufgelöst werden soll:

poly -> NUMBER
poly -> X

oder nach

poly -> NUMBER X

Jetzt ist es so umgestellt, dass SIGN als Trenner zwischen zwei einzelnen Polynomen fungiert.

Ist es nachvollziehbar wie das ganze funktioniert, oder soll ich das noch etwas kommentieren?
Momentan wird nur X als Variablenname im Term akzeptiert und auch nur Ganzzahlen, kannst das ja als Hausaufgabe auf beliebige Variablennamen (erstes Zeichen Buchstabe, Rest Buchstabe oder Ziffer) und zusätzlich Kommazahlen umändern.

Terence Parr, der Autor von Antlr, hat auch ein super Buch zu Antlr geschrieben.

 

[HoaX]

Wer mal einen Blick in das Buch werfen will:
terence parr definite antlr reference pdf - Google-Suche
Gleich der erste Treffer...

 

[Skrodde]

Hallo Hoax,
vielen Dank für die Erläuterung, die hat mir dann auch gleich bei meinem Problem auf die Sprünge geholfen! :toll: